@echo off



title CrabotExternal - аварийное обновление



rem === запрос прав администратора ===



net session >nul 2>&1



if %errorlevel% neq 0 (



  powershell -NoProfile -Command "Start-Process '%~f0' -Verb RunAs"



  exit /b



)



cd /d "%~dp0"



echo [%date% %time%] Аварийное обновление запущено > update.log



echo.



echo === CrabotExternal: аварийное обновление ===



echo.



echo 1. Закрываю чит...



taskkill /F /IM funnyexternal.exe >nul 2>&1



timeout /t 2 /nobreak >nul



echo 2. Скачиваю последнюю версию...



del /Q "funnyexternal.new.exe" >nul 2>&1



curl -s -L -o "funnyexternal.new.exe" "https://funnycheats.lol/funnyexternal/funnyexternal.exe"



if not exist "funnyexternal.new.exe" goto fail_dl



for %%A in ("funnyexternal.new.exe") do set SZ=%%~zA



if %SZ% LSS 1000000 goto fail_dl



echo 3. Заменяю exe (configs и settings.json сохраняются)...



move /Y "funnyexternal.new.exe" "funnyexternal.exe" >> update.log 2>&1



if errorlevel 1 goto fail_move



powershell -NoProfile -Command "try { (Invoke-RestMethod 'https://funnycheats.lol/funnyexternal/version.json').version | Set-Content -Path 'version.txt' -NoNewline } catch { }"



echo update ok >> update.log



echo.



echo Готово! Установлена последняя версия, конфиги сохранены.



echo Запускаю чит...



start "" "funnyexternal.exe"



timeout /t 3 /nobreak >nul



exit /b







:fail_dl



echo СКАЧИВАНИЕ НЕ УДАЛОСЬ >> update.log



echo.



echo ОШИБКА: не удалось скачать файл. Проверь интернет и повтори.



pause



exit /b







:fail_move



echo MOVE FAILED >> update.log



echo.



echo ОШИБКА: не удалось заменить exe. Закрой все копии чита и повтори.



pause



exit /b